#include

dht DHT;

// =========
// = Debug =
// set to true to output extra debugging info,
// will fill up the logs pretty quick though, not recommended for deployment
const boolean debugOut = true;
// const boolean debugOut = false;

// =========
// ================
// = Digital pins =
// ================
// digital pin for DHT11
#define DHT11_PIN 4

// set pin numbers:
// const int ledPin = 13; // the number of the LED pin
const int motorPWM = 12; // pwm control speed H-Bridge pin 1,2EN
const int motor1 = 11; // motor out pins
const int motor2 = 10; // motor out pins

// movement limit switchs
const int limitSwitch1 = 2;
const int limitSwitch2 = 3;

// low light indicator(orange)
const int lowLightIndicatorLED = 9;

// Auto/manual
const int autoManualSwitch = 5; // auto = HIGH manual = LOW
const int autoManualMove1 = 6;
const int autoManualMove2 = 7;

// =================
// = Analogue pins =
// =================
// Analogue pins LDRs
const int ldrA0 = 0;
const int ldrA1 = 3;

// ================
// = general vars =
// ================
// light limits 0 - 1023
// const int equalLight = 800; not used
const int lowLight = 200; // if either sensor registeres less than $lowLight no movement occurs
const int tolerance = 50; // if the difference between each sensor is greater than $tolerance then reposition array

// movement resolution i.e. smalles amount of time between sensor readings while array is moving
const int motorMoveFrame = 500; // m'sec, more than 2 seconds could damage the array as it moves to close to the limit switches

// sub that sets the motor on/off bit on the H-Bridge, PWM
String motorOnOff = String("off"); // or on

int ldrReadingA0;
int ldrReadingA1;

void setup() {
// initialise motor pin out
pinMode(motor1, OUTPUT);
pinMode(motor2, OUTPUT);
// limit switches
pinMode(limitSwitch1, INPUT);
pinMode(limitSwitch2, INPUT);

// low light
pinMode(lowLightIndicatorLED, OUTPUT);

// Auto/Manual Switch
pinMode(autoManualSwitch, INPUT);
pinMode(autoManualMove1, INPUT);
pinMode(autoManualMove2, INPUT);

// create serial output
Serial.begin(9600);
Serial.println("Begin Solar panel project, DC Motor H-Bridge Driver, LDRs");
Serial.println("Motor is " + motorOnOff);

if(debugOut){
Serial.println("digitalRead(limitSwitch1):"); Serial.println(digitalRead(limitSwitch1));
Serial.println("digitalRead(autoManualSwitch):"); Serial.println(digitalRead(autoManualSwitch));
// Serial.println("lowLight:" + lowLight);
// Serial.println("tolerance:" + tolerance);
// Serial.println("motorMoveFrame:" + motorMoveFrame);

}

}
void loop(){
readSensors();

while (digitalRead(autoManualSwitch) == LOW){
Serial.println("**Manual Movement Switch Engaged**");
// Manual: check manual switch selection
if (digitalRead(autoManualMove1) == HIGH || digitalRead(autoManualMove2) == HIGH){
ManualMove();
}
delay(1000); // 0.5sec
}
// Auto: got enough light?
if (ldrReadingA0 > lowLight && ldrReadingA1 > lowLight){
digitalWrite(lowLightIndicatorLED,LOW);
moveArray();
}else{
Serial.println("Light level too low");
digitalWrite(lowLightIndicatorLED,HIGH);
}

// motor off
analogWrite(motorPWM, 0);
Serial.println("Motor off");

// read DHT11 temperature and humidity
readDHT11();

delay(500); // 0.5sec
}

void ManualMove(){

if (digitalRead(autoManualMove1) == HIGH){
motorForwards();
while(digitalRead(autoManualMove1) == HIGH && digitalRead(limitSwitch1) == LOW){
delay(motorMoveFrame);
readSensors();
}
analogWrite(motorPWM, 0);
Serial.println("Motor off");
}
if (digitalRead(autoManualMove2) == HIGH){
motorBackwards();
while(digitalRead(autoManualMove2) == HIGH && digitalRead(limitSwitch2) == LOW){
delay(motorMoveFrame);
readSensors();
}
analogWrite(motorPWM, 0);
Serial.println("Motor off");
}

}

void moveArray(){

if (ldrReadingA0 > ldrReadingA1){
// might need to move array..
if ((ldrReadingA0 - ldrReadingA1) > tolerance){
// yep, ldrReadingA0 is above tolerance so move it!
if (stillOkToMoveForwards()){ motorForwards(); }
// poop, this is too sensitive, need to move array so sensors match then exit "move" sub back to wider tollerance, other wise array will keep moving
// while((ldrReadingA0 - ldrReadingA1) > tolerance && digitalRead(limitSwitch1) == LOW && ldrReadingA0 > lowLight && ldrReadingA1 > lowLight){
while(stillOkToMoveForwards()){
delay(motorMoveFrame);
readSensors();
}
}
}
if (ldrReadingA0 < ldrReadingA1){
// might need to move array..
if ((ldrReadingA1 - ldrReadingA0) > tolerance){
// yep, ldrReadingA0 is above tolerance so move it!
if (stillOkToMoveBackwards()){ motorBackwards(); }
// while((ldrReadingA1 - ldrReadingA0) > tolerance && digitalRead(limitSwitch2) == LOW && ldrReadingA0 > lowLight && ldrReadingA1 > lowLight){
while(stillOkToMoveBackwards()){
delay(motorMoveFrame);
readSensors();
}
}
}
}
boolean stillOkToMoveForwards(){
if (ldrReadingA0 > ldrReadingA1
&& digitalRead(limitSwitch1) == LOW
&& ldrReadingA0 > lowLight
&& ldrReadingA1 > lowLight
&& (digitalRead(autoManualSwitch))){
if(debugOut){ Serial.println("stillOkToMoveForwards():true"); }
return true;

}
if(debugOut){ Serial.println("stillOkToMoveForwards():false"); }
return false;
}
boolean stillOkToMoveBackwards(){
if (ldrReadingA1 > ldrReadingA0
&& digitalRead(limitSwitch2) == LOW
&& ldrReadingA0 > lowLight
&& ldrReadingA1 > lowLight
&& (digitalRead(autoManualSwitch))){
if(debugOut){ Serial.println("stillOkToMoveBackwards():true"); }
return true;

}
if(debugOut){ Serial.println("stillOkToMoveBackwards():false"); }
return false;
}
void motorForwards(){
// movement limit in this direction reached?
if(digitalRead(limitSwitch1) == LOW){
analogWrite(motorPWM, 240);
Serial.println("Motor on, moving forwards");
digitalWrite(motor1, LOW);
digitalWrite(motor2, HIGH);
Serial.println("Motor pins 0 1");
}else{ Serial.println("--- limitSwitch1 engaged ---"); }
}
void motorBackwards(){
// movement limit in this direction reached?
if(digitalRead(limitSwitch2) == LOW){
analogWrite(motorPWM, 240);
Serial.println("Motor on, moving backwards");
digitalWrite(motor2, LOW);
digitalWrite(motor1, HIGH);
Serial.println("Motor pins 1 0");
}else{ Serial.println("--- limitSwitch2 engaged ---"); }
}

void readSensors(){
ldrReadingA0 = analogRead(ldrA0);
ldrReadingA1 = analogRead(ldrA1);
Serial.print("read ldr0=");
Serial.print(ldrReadingA0);
Serial.print(" read ldr1=");
Serial.println(ldrReadingA1);
}
void readDHT11(){
// READ DATA, min 2 secs due to sensor output constraints
Serial.print("DHT11\t");
int chk = DHT.read11(DHT11_PIN);
switch (chk)
{
// case 0: Serial.print("OK,\t"); break;
case 0: break; // ok? don't print anything
case -1: Serial.print("Checksum error,\t"); break;
case -2: Serial.print("Time out error,\t"); break;
default: Serial.print("Unknown error,\t"); break;
}
// DISPLAT DATA
Serial.print("DHT.humidity\%=\"");
Serial.print(DHT.humidity,1);
Serial.print("\"\tDHT.temperature (c)=\"");
Serial.print(DHT.temperature,1);
Serial.println("\"");

delay(2000);
}